2026-04-16 오브젝트 그림자

2026-04-16 04:58:10 +09:00
parent 0fe8b18872
commit 42646a636f
303 changed files with 54374 additions and 20 deletions
--- a/Packages/com.baddog.rendering.arealight/Shaders/BadDog/BGAreaParticleLitForwardPass.hlsl
+++ b/Packages/com.baddog.rendering.arealight/Shaders/BadDog/BGAreaParticleLitForwardPass.hlsl
@@ -0,0 +1,162 @@
+#ifndef BADDOG_AREA_PARTICLES_FORWARD_LIT_PASS_INCLUDED
+#define BADDOG_AREA_PARTICLES_FORWARD_LIT_PASS_INCLUDED
+
+#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"
+#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Particles.hlsl"
+
+// Include Area Light support
+#include "Packages/com.baddog.rendering.arealight/Shaders/Include/BGAreaLighting.hlsl"
+
+void InitializeInputData(VaryingsParticle input, half3 normalTS, out InputData inputData)
+{
+    inputData = (InputData)0;
+
+    inputData.positionWS = input.positionWS.xyz;
+
+#ifdef _NORMALMAP
+    half3 viewDirWS = half3(input.normalWS.w, input.tangentWS.w, input.bitangentWS.w);
+    inputData.tangentToWorld = half3x3(input.tangentWS.xyz, input.bitangentWS.xyz, input.normalWS.xyz);
+    inputData.normalWS = TransformTangentToWorld(normalTS, inputData.tangentToWorld);
+#else
+    half3 viewDirWS = input.viewDirWS;
+    inputData.normalWS = input.normalWS;
+#endif
+
+    inputData.normalWS = NormalizeNormalPerPixel(inputData.normalWS);
+
+    viewDirWS = SafeNormalize(viewDirWS);
+
+    inputData.viewDirectionWS = viewDirWS;
+
+#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
+    inputData.shadowCoord = input.shadowCoord;
+#elif defined(MAIN_LIGHT_CALCULATE_SHADOWS)
+    inputData.shadowCoord = TransformWorldToShadowCoord(inputData.positionWS);
+#else
+    inputData.shadowCoord = float4(0, 0, 0, 0);
+#endif
+
+    inputData.fogCoord = InitializeInputDataFog(float4(input.positionWS.xyz, 1.0), input.positionWS.w);
+    inputData.vertexLighting = half3(0.0h, 0.0h, 0.0h);
+#if !defined(LIGHTMAP_ON) && (defined(PROBE_VOLUMES_L1) || defined(PROBE_VOLUMES_L2))
+    inputData.bakedGI = SAMPLE_GI(input.vertexSH,
+        GetAbsolutePositionWS(inputData.positionWS),
+        inputData.normalWS,
+        inputData.viewDirectionWS,
+        input.clipPos.xy,
+        input.probeOcclusion,
+        inputData.shadowMask);
+#else
+    inputData.bakedGI = SampleSHPixel(input.vertexSH, inputData.normalWS);
+#endif
+
+    inputData.normalizedScreenSpaceUV = GetNormalizedScreenSpaceUV(input.clipPos);
+    inputData.shadowMask = half4(1, 1, 1, 1);
+
+#if defined(DEBUG_DISPLAY) && defined(USE_APV_PROBE_OCCLUSION)
+    inputData.probeOcclusion = input.probeOcclusion;
+#endif
+
+    #if defined(DEBUG_DISPLAY) && !defined(PARTICLES_EDITOR_META_PASS)
+    inputData.vertexSH = input.vertexSH;
+    #endif
+}
+
+///////////////////////////////////////////////////////////////////////////////
+//                  Vertex and Fragment functions                            //
+///////////////////////////////////////////////////////////////////////////////
+
+VaryingsParticle ParticlesLitVertex(AttributesParticle input)
+{
+    VaryingsParticle output = (VaryingsParticle)0;
+
+    UNITY_SETUP_INSTANCE_ID(input);
+    UNITY_TRANSFER_INSTANCE_ID(input, output);
+    UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(output);
+
+    VertexPositionInputs vertexInput = GetVertexPositionInputs(input.positionOS.xyz);
+    VertexNormalInputs normalInput = GetVertexNormalInputs(input.normalOS, input.tangentOS);
+
+    half3 viewDirWS = GetWorldSpaceNormalizeViewDir(vertexInput.positionWS);
+    half3 vertexLight = VertexLighting(vertexInput.positionWS, half3(normalInput.normalWS));
+    half fogFactor = 0.0;
+    #if !defined(_FOG_FRAGMENT)
+        fogFactor = ComputeFogFactor(vertexInput.positionCS.z);
+    #endif
+
+#ifdef _NORMALMAP
+    output.normalWS = half4(normalInput.normalWS, viewDirWS.x);
+    output.tangentWS = half4(normalInput.tangentWS, viewDirWS.y);
+    output.bitangentWS = half4(normalInput.bitangentWS, viewDirWS.z);
+#else
+    output.normalWS = half3(normalInput.normalWS);
+    output.viewDirWS = viewDirWS;
+#endif
+
+#if UNITY_VERSION >= 60000000
+    OUTPUT_SH4(vertexInput.positionWS, output.normalWS.xyz, GetWorldSpaceNormalizeViewDir(vertexInput.positionWS), output.vertexSH, output.probeOcclusion);
+#else
+    OUTPUT_SH(output.normalWS.xyz, output.vertexSH);
+#endif
+
+    output.positionWS.xyz = vertexInput.positionWS;
+    output.positionWS.w = fogFactor;
+    output.clipPos = vertexInput.positionCS;
+    output.color = GetParticleColor(input.color);
+
+#if defined(_FLIPBOOKBLENDING_ON)
+#if defined(UNITY_PARTICLE_INSTANCING_ENABLED)
+    GetParticleTexcoords(output.texcoord, output.texcoord2AndBlend, input.texcoords.xyxy, 0.0);
+#else
+    GetParticleTexcoords(output.texcoord, output.texcoord2AndBlend, input.texcoords, input.texcoordBlend);
+#endif
+#else
+    GetParticleTexcoords(output.texcoord, input.texcoords.xy);
+#endif
+
+#if defined(_SOFTPARTICLES_ON) || defined(_FADING_ON) || defined(_DISTORTION_ON)
+    output.projectedPosition = vertexInput.positionNDC;
+#endif
+
+#if defined(REQUIRES_VERTEX_SHADOW_COORD_INTERPOLATOR)
+    output.shadowCoord = GetShadowCoord(vertexInput);
+#endif
+
+    return output;
+}
+
+half4 ParticlesLitFragment(VaryingsParticle input) : SV_Target
+{
+    UNITY_SETUP_INSTANCE_ID(input);
+    UNITY_SETUP_STEREO_EYE_INDEX_POST_VERTEX(input);
+
+    ParticleParams particleParams;
+    InitParticleParams(input, particleParams);
+
+    SurfaceData surfaceData;
+    InitializeParticleLitSurfaceData(particleParams, surfaceData);
+
+    InputData inputData;
+    InitializeInputData(input, surfaceData.normalTS, inputData);
+    #if UNITY_VERSION >= 60000000
+        SETUP_DEBUG_TEXTURE_DATA_FOR_TEX(inputData, input.texcoord, _BaseMap);
+    #else
+        SETUP_DEBUG_TEXTURE_DATA(inputData, input.texcoord, _BaseMap);
+    #endif
+
+    // Standard URP PBR lighting calculation
+    half4 color = UniversalFragmentPBR(inputData, surfaceData);
+
+    // Additional Area Light (only when enabled)
+    #if defined(_ENABLE_BG_AREA_LIGHTING)
+    color.rgb += EvaluateAreaLight(inputData, surfaceData);
+    #endif
+
+    color.rgb = MixFog(color.rgb, inputData.fogCoord);
+    color.a = OutputAlpha(color.a, IsSurfaceTypeTransparent(_Surface));
+
+    return color;
+}
+
+#endif // BADDOG_AREA_PARTICLES_FORWARD_LIT_PASS_INCLUDED
+